/*
  Programma:code_KY-015.ino
  Collaudo KY-015 Temperature and humidity sensor module

  Su Arduino sono utilizzati i seguenti pin
  Pin GND -> Pin GND modulo
  Pin +5V -> Pin VCC modulo
  Pin  2 -> Pin DATA modulo

  Ultima modifica il 01/01/2018
  Applicazione modificata da Adriano Gandolfo
  Sito web https://www.adrirobot.it
  Blog https://it.emcelettronica.com/author/adrirobot
  Pagina Facebook https://www.facebook.com/Adrirobot-318949048122955
  Istagram https://www.instagram.com/adrirobot/
  This example code is in the public domain.
*/


//Celsius to Kelvin conversion
double Kelvin(double celsius)
{
  return celsius + 273.15;
}

// dewPoint function NOAA
// reference (1) : http://wahiduddin.net/calc/density_algorithms.htm
// reference (2) : http://www.colorado.edu/geography/weather_station/Geog_site/about.htm
//
double dewPoint(double celsius, double humidity)
{
  // (1) Saturation Vapor Pressure = ESGG(T)
  double RATIO = 373.15 / (273.15 + celsius);
  double RHS = -7.90298 * (RATIO - 1);
  RHS += 5.02808 * log10(RATIO);
  RHS += -1.3816e-7 * (pow(10, (11.344 * (1 - 1 / RATIO ))) - 1) ;
  RHS += 8.1328e-3 * (pow(10, (-3.49149 * (RATIO - 1))) - 1) ;
  RHS += log10(1013.246);

  // factor -3 is to adjust units - Vapor Pressure SVP * humidity
  double VP = pow(10, RHS - 3) * humidity;

  // (2) DEWPOINT = F(Vapor Pressure)
  double T = log(VP / 0.61078); // temp var
  return (241.88 * T) / (17.558 - T);
}

// delta max = 0.6544 wrt dewPoint()
// 6.9 x faster than dewPoint()
// reference: https://en.wikipedia.org/wiki/Dew_point
// riferimento https://it.wikipedia.org/wiki/Punto_di_rugiada
double dewPointFast(double celsius, double humidity)
{
  double a = 17.271;
  double b = 237.7;
  double temp = (a * celsius) / (b + celsius) + log(humidity * 0.01);
  double Td = (b * temp) / (a - temp);
  return Td;
}

// Impostatione del sensore
#include "DHT.h"
#define DHTPIN 2         // Pin a cui è collegato il sensore
#define DHTTYPE DHT11    // DHT 11
DHT dht(DHTPIN, DHTTYPE);

void setup()
{
  Serial.begin(9600);
  Serial.println("DHT11 - PROGRAMA TEST");
  dht.begin();
}

void loop()
{
    // Wait a few seconds between measurements.
  delay(2000);
 
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  Serial.println("\n");
  
  Serial.print("Umidita' (%): ");
  Serial.println(h, 1);

  Serial.print("Temperatura (C): ");
  Serial.println(t, 1);

  Serial.print("Temperatura (K): ");
  Serial.println(Kelvin(t), 2);

  Serial.print("Punto di rugiada (C): ");
  Serial.println(dewPoint(t, h));

  Serial.print("Punti di rugiada fast (C): ");
  Serial.println(dewPointFast(t, h));

  delay(2000);
}

/*####################################################################
  FILE: shield_test_code_KY-015.ino
  VERSION: 1.0
  Descrizione: Test KY-015 Temperature and humidity sensor module

  Su Arduino sono utilizzati i seguenti pin
  Pin GND -> Pin GND modulo
  Pin +5V -> Pin VCC modulo
  Pin  2 -> Pin DATA modulo

  Ultima modifica il 14/01/2019
  Applicazione modificata da Adriano Gandolfo
  Sito web https://www.adrirobot.it
  Blog https://it.emcelettronica.com/author/adrirobot
  Pagina Facebook https://www.facebook.com/Adrirobot-318949048122955
  Istagram https://www.instagram.com/adrirobot/
  This example code is in the public domain.
  #################################################################### */

// Definizione dei pin di collegamento
#define sclk 13
#define mosi 11
#define cs   10
#define rst  9
#define dc   8

// Impostazione del sensore DHT11
#include "DHT.h"
#define DHTPIN 2         // Pin a cui è collegato il sensore
#define DHTTYPE DHT11    // DHT 11
DHT dht(DHTPIN, DHTTYPE);

// Definizione dei colori
#define BLACK           0x0000
#define BLUE            0x001F
#define RED             0xF800
#define GREEN           0x07E0
#define CYAN            0x07FF
#define MAGENTA         0xF81F
#define YELLOW          0xFFE0
#define WHITE           0xFFFF

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1331.h>
#include <SPI.h>

Adafruit_SSD1331 display = Adafruit_SSD1331(cs, dc, rst);

void setup()   {
  Serial.begin(9600);
  display.begin();
  dht.begin();

  // Messaggio iniziale
  display.fillScreen(BLACK);
  display.setTextSize(1);
  display.setTextColor(BLUE);
  display.setRotation(2); //Ruota display
  display.setCursor(0, 0);
  display.println("www.adrirobot.it");
  display.println("");
  display.setTextColor(GREEN);
  display.println("Multitest shield");
  display.println("");
  display.println("    TEST FOR   ");
  display.println(" 37 IN 1 SENSOR ");
  delay(3000);
  display.fillScreen(BLACK);
  display.setTextColor(YELLOW);
  display.setCursor(0, 0);
  display.println("   TEST MODUL0  ");
  display.println("");
  display.setTextColor(CYAN);
  display.println("KY-015 Temp. and");
  display.println(" umidity sensor ");
  display.println("");
  delay (200);
}

void loop()
{
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  Serial.println("\n");
  Serial.print("Umidita' (%): ");
  Serial.println(h, 1);
  Serial.print("Temperatura (C): ");
  Serial.println(t, 1);

  display.fillRect(0, 40, 96, 30, BLACK);
  display.setCursor(0, 40);

  display.setTextColor(WHITE);
  display.print("Umidita' %: ");
  display.setTextColor(RED);
  display.println(h, 1);

  display.println("");
  display.setTextColor(WHITE);
  display.print("Temp.    C: ");
  display.setTextColor(GREEN);
  display.println(t, 1);

  delay (1000); // Pausa di 1 secondo
}