/*  Programma:test_sensore_pir.ino 
Il programma accende un led quando un corpo caldo
è in movimento.
di Adriano Gandolfo  https://www.adrirobot.it
*/

//Definizione dei PIN
int pirPin = 2;    //il PIN di Arduino a cui è collegato il sensore
int ledPin = 13;   //il PIN a cui è connesso il LED

// Tempo di calibrazione del sensore
int calibrationTime = 30;

//Il tempo in cui l'uscita sia bassa
long unsigned int lowIn;

// valore di millisecondi, per cui si ritiene che ci sia "quiete"
long unsigned int pause = 5000;

boolean lockLow = true;
boolean takeLowTime;

// Impostazione del sensore
void setup() {
  Serial.begin(9600);
  pinMode(pirPin, INPUT);
  pinMode(ledPin, OUTPUT);
  digitalWrite(pirPin, LOW);

  //Fase di calibrazione
  Serial.print("Calibrazione del sensore ");
  for (int i = 0; i < calibrationTime; i++) {
    Serial.print(".");
    delay(1000);
  }
  Serial.println(" Fatto");
  Serial.println("SENSORE ATTIVO");
  delay(50);
}

void loop() {

  // Questo IF permette di stabilre se il sensore rileva un oggetto in movimento
  if (digitalRead(pirPin) == HIGH) {
    digitalWrite(ledPin, HIGH);   //Accendiamo il LED
    if (lockLow) {

      lockLow = false;
      Serial.println("---");
      Serial.print("Movimento rilevato a ");
      Serial.print(millis() / 1000);
      Serial.println(" sec");
      delay(50);
    }
    takeLowTime = true;
  }
  // Questo IF permette di stabilire se non c'è più nessun movimento
  if (digitalRead(pirPin) == LOW) {
    digitalWrite(ledPin, LOW);  //Si spegne il LED

    if (takeLowTime) {
      lowIn = millis();
      takeLowTime = false;
    }

    if (!lockLow && millis() - lowIn > pause) {

      lockLow = true;
      Serial.print("Movimento terminato a ");      //output
      Serial.print((millis() - pause) / 1000);
      Serial.println(" sec");
      delay(50);
    }
  }
}

Visualizza questo post su Instagram

Test sensore PIR HC-SR501 con Multi test shield - sistema di allarme. #arduinouno #arduinomodules #sensors #sensor #hc_sr501 #pir_sensor

Un post condiviso da Adriano Gandolfo (@adrirobot) in data: Mar 15, 2019 at 11:25 PDT

/*####################################################################
  FILE: allarme_pir_HC-SR501_SHIELD.ino
  VERSION: 1.0
  Quando viene rilevato un movimento viene attivayo un relè
  il led passa dal verde al rosso e viene emesso un suono
  Sul display viene segnalato lo stato del sensore

  Creato il 07/11/2018 da Adriano Gandolfo
  Sito web http://www.adrirobot.it
  Blog http://it.emcelettronica.com/author/adrirobot
  Pagina Facebook https://www.facebook.com/Adrirobot-318949048122955
  Istagram https://www.instagram.com/adrirobot/
  This example code is in the public domain.
  #################################################################### */

// Definizione dei pin di collegamento
#define sclk 13
#define mosi 11
#define cs   10
#define rst  9
#define dc   8

//Definizione dei PIN
#define pirPin 17   // pin per il sensore HC-SR501  
#define pinRele 2   // pin per il mudulo KY-019 5V relay module
#define greenpin 5  // pin per il LED verde KY-011 2 color LED module
#define redpin 6    // pin per il LED rosso KY-011 2 color LED module
#define buzzerPin 4 // Pin per il  KY-006 Small passive buzzer module

// Tempo di calibrazione del sensore
int calibrationTime = 10;

//Il tempo in cui l'uscita sia bassa
long unsigned int lowIn;

// valore di millisecondi, per cui si ritiene che ci sia "quiete"
long unsigned int pause = 3000;

boolean lockLow = true;
boolean takeLowTime;


// Definizione dei colori
#define BLACK           0x0000
#define BLUE            0x001F
#define RED             0xF800
#define GREEN           0x07E0
#define CYAN            0x07FF
#define MAGENTA         0xF81F
#define YELLOW          0xFFE0
#define WHITE           0xFFFF

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1331.h>
#include <SPI.h>

Adafruit_SSD1331 display = Adafruit_SSD1331(cs, dc, rst);

// Impostazione del sensore
void setup() {
  Serial.begin(9600);
  display.begin();
  pinMode(pirPin, INPUT);
  pinMode (pinRele, OUTPUT);
  pinMode(greenpin, OUTPUT);
  pinMode(redpin, OUTPUT);
  pinMode(buzzerPin, OUTPUT);
  digitalWrite(pirPin, LOW);

  // Messaggio iniziale
  display.fillScreen(BLACK);
  display.setTextSize(1);
  display.setTextColor(BLUE);
  display.setRotation(2); //Ruota display
  display.setCursor(0, 0);
  display.println("www.adrirobot.it");
  display.println("");
  display.setTextColor(GREEN);
  display.println("Multitest shield");
  display.println("");
  display.println("Allarme con PIR");
  display.println("Sensore HC-SR501");
  delay(2000);

  //Fase di calibrazione
  Serial.print("Calibrazione del sensore ");
  display.fillScreen(BLACK);
  display.setTextColor(BLUE);
  display.setCursor(0, 0);
  display.println("CALIBRAZIONE");

  for (int i = 0; i < calibrationTime; i++) {
    Serial.print(".");
    delay(1000);
  }
  Serial.println(" Fatto");
  Serial.println("SENSORE ATTIVO");
  display.fillScreen(BLACK);
  display.setTextColor(BLUE);
  display.setCursor(0, 0);
  display.print("SENSORE ATTIVO");
  tone(buzzerPin, 1000, 500);   //suona una nota alla frequenza di 1000Hz
  delay(1000);
  digitalWrite (redpin, LOW); // spegne led rosso
  digitalWrite (greenpin, HIGH); // accende led verde
  display.fillScreen(BLACK);
  display.setTextColor(YELLOW);
  display.setCursor(0, 0);
  display.println("STATO ALLARME");
  delay(50);
}

void loop() {

  // Questo IF permette di stabilre se il sensore rileva un oggetto in movimento
  if (digitalRead(pirPin) == HIGH) {
    digitalWrite (redpin, HIGH); // accende led rosso
    digitalWrite (greenpin, LOW); // spegne led
    digitalWrite(pinRele, HIGH);

    if (lockLow) {

      lockLow = false;
      Serial.println("---");
      Serial.print("Movimento rilevato a ");
      digitalWrite (redpin, HIGH); // accende led rosso
      digitalWrite (greenpin, LOW); // spegne led     display.fillRect(0, 45, 96, 15, BLACK);
      display.fillRect(0, 45, 96, 15, BLACK);
      display.setCursor(0, 45);
      display.setTextColor(RED);
      display.print("ALLARME");
      tone(buzzerPin, 500, 500);   //suona una nota alla frequenza di 1000Hz
      digitalWrite(pinRele, HIGH);
      Serial.print(millis() / 1000);
      Serial.println(" sec");
      delay(50);
    }
    takeLowTime = true;
  }
  // Questo IF permette di stabilire se non c'è più nessun movimento
  if (digitalRead(pirPin) == LOW) {
    digitalWrite (redpin, LOW); // spegne led rosso
    digitalWrite (greenpin, HIGH); // accende led verde
    display.fillRect(0, 45, 96, 15, BLACK);
    display.setCursor(0, 45);
    display.setTextColor(GREEN);
    display.print("NESSUNO");
    digitalWrite(pinRele, LOW);
    if (takeLowTime) {
      lowIn = millis();
      takeLowTime = false;
    }

    if (!lockLow && millis() - lowIn > pause) {

      lockLow = true;
      Serial.print("Movimento terminato a ");      //output
      Serial.print((millis() - pause) / 1000);
      Serial.println(" sec");
      delay(50);
    }
  }
}