TCS3200 RGB Color sensor

/*
  Test_TS3200.ino
  Il programma riconosce i colori primari: Rosso, Verde e Blu degli
  oggetti posti di fronte al sensore TS 3200 e accende il relativo
  Led colorato sul Modulo KY-009.  Comunica a voce tramite il modulo
  JQ6500 il colore riconosciuto.

  Sono utilizzati i seguenti pin
  Pin +5V           -> Alimentazione Color sensor, JQ6500
  Pin GND           -> GND Color sensor, JQ6500, KY-009
  Pin Digital 2     -> Out Color sensor
  Pin Digital 3     -> S0 Color sensor
  Pin Digital 4     -> S1 Color sensor
  Pin Digital 5     -> S2 Color sensor
  Pin Digital 6     -> S3 Color sensor
  Pin Digital 8     -> Led Rosso KY-009
  Pin Digital 9     -> Led Verde KY-009
  Pin Digital 10    -> Led Blu KY-009
  Pin Digital 11    -> RX JQ6500
  Pin Digital 12    -> TX JQ6500

  Creato il 03/05/2016 da Adriano Gandolfo
  Sito web https://www.adrirobot.it
  Blog http://it.emcelettronica.com/author/adrirobot
  Pagina Facebook https://www.facebook.com/Adrirobot-318949048122955
  Istagram https://www.instagram.com/adrirobot/
  This example code is in the public domain.
*/

#include <Arduino.h>
#include <SoftwareSerial.h>
#include <JQ6500_Serial.h>

//Pin color sensor
const int out = 2;
const int s0 = 3;
const int s1 = 4;
const int s2 = 5;
const int s3 = 6;

// LED pins connected to Arduino
int redLed = 8;
int greenLed = 9;
int blueLed = 10;

// Pin di comunicazione con modulo JQ6500
int TX = 12;
int RX = 11;

// Variables
int red = 0;
int green = 0;
int blue = 0;

// Impostazione modulo JQ6500
JQ6500_Serial mp3(TX, RX);

void setup()
{
  Serial.begin(9600);
  pinMode(s0, OUTPUT);
  pinMode(s1, OUTPUT);
  pinMode(s2, OUTPUT);
  pinMode(s3, OUTPUT);
  pinMode(out, INPUT);
  pinMode(redLed, OUTPUT);
  pinMode(greenLed, OUTPUT);
  pinMode(blueLed, OUTPUT);
  mp3.begin(9600);
  mp3.reset();
  mp3.setVolume(30);
  mp3.setLoopMode(MP3_LOOP_NONE);
  digitalWrite(s0, HIGH);
  digitalWrite(s1, HIGH);
}

void loop()
{
  color();
  Serial.print("R Intensity:");
  Serial.print(red, DEC);
  Serial.print(" G Intensity: ");
  Serial.print(green, DEC);
  Serial.print(" B Intensity : ");
  Serial.print(blue, DEC);
  //Serial.println();

  if (red < blue && red < green && red < 20)
  {
    Serial.println(" - (Red Color)");
    digitalWrite(redLed, HIGH); // Accendo Led Rosso
    digitalWrite(greenLed, LOW);
    digitalWrite(blueLed, LOW);
    mp3.playFileByIndexNumber(2); //Frase LED ROSSO
    delay (1000);
  }

  else if (blue < red && blue < green)
  {
    Serial.println(" - (Blue Color)");
    digitalWrite(redLed, LOW);
    digitalWrite(greenLed, LOW);
    digitalWrite(blueLed, HIGH); // Accende Led Blu
    mp3.playFileByIndexNumber(3); //Frase LED BLU
    delay (1000);
  }

  else if (green < red && green < blue)
  {
    Serial.println(" - (Green Color)");
    digitalWrite(redLed, LOW);
    digitalWrite(greenLed, HIGH); // Accende Led Verde
    digitalWrite(blueLed, LOW);
    mp3.playFileByIndexNumber(1); //Frase LED VERDE
    delay (1000);
  }
  else {
    Serial.println();
  }
  delay(300);
  digitalWrite(redLed, LOW);
  digitalWrite(greenLed, LOW);
  digitalWrite(blueLed, LOW);
}

void color()
{
  digitalWrite(s2, LOW);
  digitalWrite(s3, LOW);
  //count OUT, pRed, RED
  red = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH);
  digitalWrite(s3, HIGH);
  //count OUT, pBLUE, BLUE
  blue = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH);
  digitalWrite(s2, HIGH);
  //count OUT, pGreen, GREEN
  green = pulseIn(out, digitalRead(out) == HIGH ? LOW : HIGH);
}

TCS3200 Programmable color light-to-frequency converter

Piedinatura	Datasheet	Foto dell'integrato


Scheda Arduino UNO R3	TCS3200 RGB Color sensor

Modulo JQ6500	Modulo KY-009 RGB full color LED

Cavi colorati M/M M/F	Breadboard
150Ω (marrone, verde, marrone), 100Ω (marrone , nero, marrone), 100Ω (marrone , nero, marrone). 1KΩ (marrone , nero, rosso)
Resistenze di vario valore	Altoparlante 8 Ω 0,5 W

Indice

Descrizione

Specifiche tecniche

Esempio di utilizzo del sensore

Scheda Arduino UNO

Modulo JQ6500

KY-009 RGB full color LED Module

Mini breadboard

Schema dei collegamenti

Riassunto materiale necessario

Listato del programma

Elenco revisioni:
04/06/2017	Emissione preliminare